Yerleşimlerle verimli görselleştirmeler

Julia ile Veri Görselleştirmeye Giriş

Gustavo Vieira Suñe

Data Analyst

Yerleşimler

Tek figürde birden çok eğri

K-Pop dinleme sıklığına göre gruplandırılmış yaş dağılımını gösteren bir yoğunluk grafiği; her kategori için aynı figürde bir eğri.

Grafik ızgarası (layout)

İki-bire iki ızgarada, K-Pop dinleme sıklığının her bir düzeyi için yaş dağılımını gösteren yoğunluk grafikleri. Her grafiğin çizgi rengi farklıdır.

Izgara

using StatsPlots, DataFrames, CSV

# Veri kümesini yükleyin
streaming = DataFrame(
    CSV.File("streaming.csv")
)

# Yoğunluk grafiği oluşturun
density(
    streaming.Age,
    group=streaming."Frequency [K pop]",
    linewidth=2.5,

    # Yerleşimi ayarlayın
    layout=4,
)

İki-bire iki ızgarada, K-Pop dinleme sıklığının her bir düzeyi için yaş dağılımını gösteren yoğunluk grafikleri. Tüm grafiklerin çizgi rengi aynıdır.

Izgara öğelerini özelleştirme

using Colors

# Julia logo renkleri
logocolors = Colors.JULIA_LOGO_COLORS
colors = [logocolors.blue logocolors.red
    logocolors.green logocolors.purple]

density(
    streaming.Age,
    group=streaming."Frequency [K pop]",
    linewidth=2.5,
    layout=4,
    # Çizgi renkleri
    linecolor=colors,
)

İki-bire iki ızgarada, K-Pop dinleme sıklığının her bir düzeyi için yaş dağılımını gösteren yoğunluk grafikleri. Her grafiğin çizgi rengi farklıdır.

Izgara yerleşimini kontrol etme

density(
    streaming.Age,
    group=streaming."Frequency [K pop]",
    linewidth=2.5,
    linecolor=colors,

    # Yerleşim boyutları
    layout=(4, 1),

    # Eksen etiketleri
    xlabel=["" "" "" "Age"],
    ylabel="Probability",
)

# Eksen sınırları
xlims!(10, 80)
ylims!(0, 0.2)

Dört-bire bir ızgarada, K-Pop dinleme sıklığının her bir düzeyi için yaş dağılımını gösteren yoğunluk grafikleri. Her grafiğin çizgi rengi farklıdır.

Gelişmiş yerleşimler

Bir grafik ızgarası. Üst sırada iki kutu grafiği: yaş ve anksiyete düzeyi, akış hizmetine göre. Alt sırada her akış hizmeti için yaş dağılımını gösteren üç histogram.

Adım adım

theme(:wong)
# Renkleri seçin
colors = [:purple :green3 :firebrick1]


# İlk kutu grafiği
p1 = boxplot(streaming."Streaming service",
    streaming.Age,

    # Akış hizmetine göre gruplayın
    group=streaming."Streaming service",
    color=colors,

    label=false,
    ylabel="Age",
    # Aykırı değerleri kaldırın
    outliers=false)

Akış hizmetine göre yaş dağılımını gösteren bir kutu grafiği.

Adım adım

# İkinci kutu grafiği
p2 = boxplot(
    streaming."Streaming service",
    streaming.Anxiety,
    # Akış hizmetine göre gruplayın
    group=streaming."Streaming service",
    color=colors,
    label=false,
    ylabel="Anxiety",
    # Aykırı değerleri kaldırın
    outliers=false,
)

Akış hizmetine göre anksiyete düzeyi dağılımını gösteren bir kutu grafiği.

Adım adım

# Histogramlar
p3 = histogram(
    streaming.Age,
    group=streaming."Streaming service",
    color=colors,
    # Çizgileri kaldırın
    linewidth=0,

    # Yerleşimi ayarlayın
    layout=(1, 3),

    xlabel="Age",
    # Y-ekseni etiketleri
    ylabel=["Frequency" "" ""]
)

Her akış hizmeti için yaş dağılımını gösteren üç histogram.

Grafikleri birleştirme

# Yerleşimi seçin
layout = @layout [a b; c]

Grafiğin yerleşim yapısını gösteren bir şekil.

# Grafikleri birleştirin
plot(p1, p2, p3, layout=layout)

Bir grafik ızgarası. Üst sırada iki kutu grafiği: yaş ve anksiyete düzeyi, akış hizmetine göre. Alt sırada her akış hizmeti için yaş dağılımını gösteren üç histogram.

Hadi pratik yapalım!

Julia ile Veri Görselleştirmeye Giriş