Visualisasi efisien dengan layout

Pengantar Visualisasi Data dengan Julia

Gustavo Vieira Suñe

Data Analyst

Layout

Beberapa kurva dalam satu figur

Plot densitas yang menampilkan sebaran usia dikelompokkan menurut frekuensi mendengarkan K-Pop, satu kurva per kategori dalam figur yang sama.

Grid plot (layout)

Kisi 2x2 plot densitas yang menampilkan sebaran usia, satu plot untuk tiap frekuensi mendengarkan K-Pop. Garis tiap plot berwarna berbeda.

Grid

using StatsPlots, DataFrames, CSV

# Muat dataset
streaming = DataFrame(
    CSV.File("streaming.csv")
)

# Buat plot densitas
density(
    streaming.Age,
    group=streaming."Frequency [K pop]",
    linewidth=2.5,

    # Atur layout
    layout=4,
)

Kisi 2x2 plot densitas yang menampilkan sebaran usia, satu plot untuk tiap frekuensi mendengarkan K-Pop. Semua plot memiliki warna garis yang sama.

Kustomisasi elemen grid

using Colors

# Warna logo Julia
logocolors = Colors.JULIA_LOGO_COLORS
colors = [logocolors.blue logocolors.red
    logocolors.green logocolors.purple]

density(
    streaming.Age,
    group=streaming."Frequency [K pop]",
    linewidth=2.5,
    layout=4,
    # Warna garis
    linecolor=colors,
)

Kisi 2x2 plot densitas yang menampilkan sebaran usia, satu plot untuk tiap frekuensi mendengarkan K-Pop. Garis tiap plot berwarna berbeda.

Mengatur grid layout

density(
    streaming.Age,
    group=streaming."Frequency [K pop]",
    linewidth=2.5,
    linecolor=colors,

    # Dimensi layout
    layout=(4, 1),

    # Label sumbu
    xlabel=["" "" "" "Age"],
    ylabel="Probability",
)

# Batas sumbu
xlims!(10, 80)
ylims!(0, 0.2)

Kisi 4x1 plot densitas yang menampilkan sebaran usia, satu plot untuk tiap frekuensi mendengarkan K-Pop. Garis tiap plot berwarna berbeda.

Layout lanjutan

Sebuah grid plot. Baris atas menampilkan dua box plot: usia dan tingkat kecemasan vs layanan streaming. Baris bawah memiliki tiga histogram sebaran usia per layanan streaming.

Langkah demi langkah

theme(:wong)
# Pilih warna
colors = [:purple :green3 :firebrick1]


# Box plot pertama
p1 = boxplot(streaming."Streaming service",
    streaming.Age,

    # Kelompokkan menurut layanan streaming
    group=streaming."Streaming service",
    color=colors,

    label=false,
    ylabel="Age",
    # Hapus pencilan
    outliers=false)

Sebuah box plot yang menampilkan sebaran usia per layanan streaming.

Langkah demi langkah

# Box plot kedua
p2 = boxplot(
    streaming."Streaming service",
    streaming.Anxiety,
    # Kelompokkan menurut layanan streaming
    group=streaming."Streaming service",
    color=colors,
    label=false,
    ylabel="Anxiety",
    # Hapus pencilan
    outliers=false,
)

Sebuah box plot yang menampilkan sebaran tingkat kecemasan per layanan streaming.

Langkah demi langkah

# Histogram
p3 = histogram(
    streaming.Age,
    group=streaming."Streaming service",
    color=colors,
    # Hapus garis
    linewidth=0,

    # Atur layout
    layout=(1, 3),

    xlabel="Age",
    # Atur label sumbu-y
    ylabel=["Frequency" "" ""]
)

Tiga histogram yang menampilkan sebaran usia untuk tiap layanan streaming.

Menggabungkan plot

# Pilih layout
layout = @layout [a b; c]

Sebuah figur yang menampilkan struktur layout plot.

# Gabungkan plot
plot(p1, p2, p3, layout=layout)

Sebuah grid plot. Baris atas menampilkan dua box plot: usia dan tingkat kecemasan vs layanan streaming. Baris bawah memiliki tiga histogram sebaran usia per layanan streaming.

Ayo berlatih!

Pengantar Visualisasi Data dengan Julia