Visualizzazioni efficienti con i layout

Introduzione alla visualizzazione dei dati con Julia

Gustavo Vieira Suñe

Data Analyst

Layout

Più curve in un’unica figura

Un grafico di densità che mostra la distribuzione delle età raggruppata per frequenza di ascolto di K‑Pop, una curva per categoria nella stessa figura.

Griglia di grafici (layout)

Una griglia 2x2 di grafici di densità che mostra la distribuzione delle età, uno per ogni frequenza di ascolto di K‑Pop. La linea di ogni grafico ha un colore diverso.

La griglia

using StatsPlots, DataFrames, CSV

# Carica il dataset
streaming = DataFrame(
    CSV.File("streaming.csv")
)

# Crea grafico di densità
density(
    streaming.Age,
    group=streaming."Frequency [K pop]",
    linewidth=2.5,

    # Imposta layout
    layout=4,
)

Una griglia 2x2 di grafici di densità che mostra la distribuzione delle età, uno per ogni frequenza di ascolto di K‑Pop. Tutte le linee hanno lo stesso colore.

Personalizzare gli elementi della griglia

using Colors

# Colori del logo Julia
logocolors = Colors.JULIA_LOGO_COLORS
colors = [logocolors.blue logocolors.red
    logocolors.green logocolors.purple]

density(
    streaming.Age,
    group=streaming."Frequency [K pop]",
    linewidth=2.5,
    layout=4,
    # Colori delle linee
    linecolor=colors,
)

Una griglia 2x2 di grafici di densità che mostra la distribuzione delle età, uno per ogni frequenza di ascolto di K‑Pop. La linea di ogni grafico ha un colore diverso.

Controllare il layout a griglia

density(
    streaming.Age,
    group=streaming."Frequency [K pop]",
    linewidth=2.5,
    linecolor=colors,

    # Dimensioni del layout
    layout=(4, 1),

    # Etichette assi
    xlabel=["" "" "" "Age"],
    ylabel="Probability",
)

# Limiti assi
xlims!(10, 80)
ylims!(0, 0.2)

Una griglia 4x1 di grafici di densità che mostrano la distribuzione delle età, uno per ogni frequenza di ascolto di K‑Pop. Ogni linea ha un colore diverso.

Layout avanzati

Una griglia di grafici. La riga superiore mostra due box plot: età e livelli di ansia per servizio di streaming. La riga inferiore ha tre istogrammi con la distribuzione delle età per ciascun servizio.

Passo dopo passo

theme(:wong)
# Scegli i colori
colors = [:purple :green3 :firebrick1]


# Primo box plot
p1 = boxplot(streaming."Streaming service",
    streaming.Age,

    # Raggruppa per servizio di streaming
    group=streaming."Streaming service",
    color=colors,

    label=false,
    ylabel="Age",
    # Rimuovi outlier
    outliers=false)

Un box plot che mostra la distribuzione delle età per servizio di streaming.

Passo dopo passo

# Secondo box plot
p2 = boxplot(
    streaming."Streaming service",
    streaming.Anxiety,
    # Raggruppa per servizio di streaming
    group=streaming."Streaming service",
    color=colors,
    label=false,
    ylabel="Anxiety",
    # Rimuovi outlier
    outliers=false,
)

Un box plot che mostra la distribuzione dei livelli di ansia per servizio di streaming.

Passo dopo passo

# Istogrammi
p3 = histogram(
    streaming.Age,
    group=streaming."Streaming service",
    color=colors,
    # Rimuovi linee
    linewidth=0,

    # Imposta layout
    layout=(1, 3),

    xlabel="Age",
    # Etichette asse y
    ylabel=["Frequency" "" ""]
)

Tre istogrammi che mostrano la distribuzione delle età per ciascun servizio di streaming.

Unire i grafici

# Seleziona il layout
layout = @layout [a b; c]

Una figura che mostra la struttura del layout del grafico.

# Unisci i grafici
plot(p1, p2, p3, layout=layout)

Una griglia di grafici. La riga superiore mostra due box plot, uno di età e l’altro di livelli di ansia per servizio di streaming. La riga inferiore ha tre istogrammi con la distribuzione delle età per ciascun servizio.

Passons à la pratique !

Introduzione alla visualizzazione dei dati con Julia