Wydajne wizualizacje z układami

Wprowadzenie do wizualizacji danych w Julii

Gustavo Vieira Suñe

Data Analyst

Układy

Wiele krzywych na jednym wykresie

Wykres gęstości pokazujący rozkład wieku pogrupowany według częstotliwości słuchania K-Popu – jedna krzywa na kategorię w tym samym wykresie.

Siatka wykresów (layout)

Siatka 2x2 wykresów gęstości pokazująca rozkład wieku – jeden wykres na każdą częstotliwość słuchania K-Popu. Linia każdego wykresu ma inny kolor.

Siatka

using StatsPlots, DataFrames, CSV

# Load dataset
streaming = DataFrame(
    CSV.File("streaming.csv")
)

# Create density plot
density(
    streaming.Age,
    group=streaming."Frequency [K pop]",
    linewidth=2.5,

    # Set layout
    layout=4,
)

Siatka 2x2 wykresów gęstości pokazująca rozkład wieku – jeden wykres na każdą częstotliwość słuchania K-Popu. Wszystkie wykresy mają taki sam kolor linii.

Dostosowywanie elementów siatki

using Colors

# Julia logo colors
logocolors = Colors.JULIA_LOGO_COLORS
colors = [logocolors.blue logocolors.red
    logocolors.green logocolors.purple]

density(
    streaming.Age,
    group=streaming."Frequency [K pop]",
    linewidth=2.5,
    layout=4,
    # Line colors
    linecolor=colors,
)

Siatka 2x2 wykresów gęstości pokazująca rozkład wieku – jeden wykres na każdą częstotliwość słuchania K-Popu. Linia każdego wykresu ma inny kolor.

Kontrolowanie układu siatki

density(
    streaming.Age,
    group=streaming."Frequency [K pop]",
    linewidth=2.5,
    linecolor=colors,

    # Layout dimensions
    layout=(4, 1),

    # Axis labels
    xlabel=["" "" "" "Age"],
    ylabel="Probability",
)

# Axis bounds
xlims!(10, 80)
ylims!(0, 0.2)

Siatka czterech wykresów gęstości w układzie 4x1 pokazująca rozkład wieku – jeden wykres na każdą częstotliwość słuchania K-Popu. Linia każdego wykresu ma inny kolor.

Zaawansowane układy

Siatka wykresów. Górny wiersz zawiera dwa wykresy pudełkowe – jeden dla wieku i jeden dla poziomu lęku względem serwisu streamingowego. Dolny wiersz zawiera trzy histogramy rozkładu wieku dla każdego serwisu.

Krok po kroku

theme(:wong)
# Choose colors
colors = [:purple :green3 :firebrick1]


# First box plot
p1 = boxplot(streaming."Streaming service",
    streaming.Age,

    # Group by streaming service
    group=streaming."Streaming service",
    color=colors,

    label=false,
    ylabel="Age",
    # Remove outliers
    outliers=false)

Wykres pudełkowy pokazujący rozkład wieku dla każdego serwisu streamingowego.

Krok po kroku

# Second box plot
p2 = boxplot(
    streaming."Streaming service",
    streaming.Anxiety,
    # Group by streaming service
    group=streaming."Streaming service",
    color=colors,
    label=false,
    ylabel="Anxiety",
    # Remove outliers
    outliers=false,
)

Wykres pudełkowy pokazujący rozkład poziomu lęku dla każdego serwisu streamingowego.

Krok po kroku

# Histograms
p3 = histogram(
    streaming.Age,
    group=streaming."Streaming service",
    color=colors,
    # Remove lines
    linewidth=0,

    # Set layout
    layout=(1, 3),

    xlabel="Age",
    # Set y-axis labels
    ylabel=["Frequency" "" ""]
)

Trzy histogramy pokazujące rozkład wieku dla każdego serwisu streamingowego.

Łączenie wykresów

# Select layout
layout = @layout [a b; c]

Rysunek przedstawiający strukturę układu wykresu.

# Join the plots
plot(p1, p2, p3, layout=layout)

Czas na ćwiczenia!

Wprowadzenie do wizualizacji danych w Julii